📂力学系

チュア回路

システム ^{1 2}

$$ \begin{align*} \dot{x} =& \alpha (y - h(x)) \\ \dot{y} =& x - y + z \\ \dot{z} =& -\beta y \\ h(x) =& m_{1} x + \frac{1}{2} (m_{0} - m_{1}) \left( \left| x + 1 \right| - \left| x - 1 \right| \right) \end{align*} $$

説明

チュア回路^{Chua’s circuit}の$N_{R}$はいわゆるチュアダイオード^{Chua diode}と呼ばれ、回路で非線形抵抗を実装する素子であるという。$h$が必ず決まっているわけではないが、ノンスムーズなシステムを想定するときはたいていあのような形を用いる。$h$があのように定義される場合、チュア回路は区分ごとに線形なシステムとなる。

参考までに、このような回路を考案して研究したレオン・チュア^{Leon Ong Chua}はフィリピン出身の電気工学者であり、チュアは漢字で蔡と書く。我々でいえば蔡氏回路程度に呼ぶこともできるだろう。

アトラクター

チュア回路は次のようにカオスアトラクターを持つ。

分岐図

次は$\beta = 15$、$m_{0} = -1/7$、$m_{1} = 2/7$とおき、$\alpha$を分岐パラメータとして得たチュア回路の分岐図である。

コード

次はチュア回路のアトラクターと分岐図を再現するJuliaコードである。

using DataFrames, DifferentialEquations, OrdinaryDiffEqLowOrderRK

function factory_chua(α::Number; ic = [0.4, -0.2, 0.2], saveat = 0:1e-2:100)
     β,   m0,  m1 = (
    15, -1/7, 2/7)
    h(x) = m1*x + (m0 - m1)*(abs(x + 1) - abs(x - 1))/2
    function sys(du, u, p, t)
        x, y, z = u
        α = p[1]

        du[1] = α*(y - h(x))
        du[2] = x - y + z
        du[3] = -β*y
        return du
    end
    sol = solve(ODEProblem(sys, ic, (0, last(saveat)), [α]), RK4(), dt = saveat.step.hi, adaptive=false, maxiters = 1e+7)
    matrix = Matrix([sol.t'; sol[:, :]; stack([sys(zeros(3), u, [α], 0) for u in sol.u])]')
    return matrix[sol.t .≥ first(saveat), :][1:end-1, :]
end
factory_chua(T::Type, args...; kargs...) =
DataFrame(factory_chua(args...; kargs...), ["t", "x", "y", "z", "dx", "dy", "dz"])

sol = factory_chua(DataFrame, 8.8)
plot(sol.x, sol.y, sol.z, alpha = .5, color = :black, xlabel = L"x", ylabel = L"y", zlabel = L"z", size = [400, 400])

pm, pM = 8.430, 8.8; p0, p1 = 8.79, 8.80;
p_ = range(pm, pM, length = 1001)
bfcn = callbfcn("G:/BF/chua/bfcnA.jld2")
@showprogress @threads for k in eachindex(p_)
    sol = factory_chua(DataFrame, p_[k], saveat = 0:1e-3:3000)
    z_ = sol.z[sol.t .≥ 2000]
    bfcn[p_[k]] = z_[arglmax(z_)]
end
scatter(dict2bifurcation(bfcn)..., xticks = [pm, p0, p1, pM], ms = .5, ma = .5, msw = 0, color = :black); png("temp")